home *** CD-ROM | disk | FTP | other *** search
/ Compute! Gazette 1984 May / 1984-05.d64 / begin corner_vic (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  1KB  |  42 lines
  1. 5 rem stepping up or down
  2. 10 goto 100
  3. 20 print"press return"
  4. 22 geta$:ifa$=""then22
  5. 24 if asc(a$)<>13then22
  6. 26 return
  7. 30 for d=1 to 80:next d:poke s,0:return
  8. 40 for d=1 to 500:next d:poke s,0:return
  9. 100 print"[147]":print"stepping up or down"
  10. 110 print"two notes are shown.":print"from the first one,"
  11. 120 print"do you go up, go down":print"or stay the same":print"to play the second?"
  12. 130 print"press  f1 for up":printtab(7)"f3 for same":printtab(7)"f5 for down"
  13. 140 l$="[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
  14. 150 for i=0to8:readf(i):next
  15. 160 data 232,231,228,225,223,219,215,209,207
  16. 170 b(1)=135:b(2)=134:b(3)=133
  17. 175 poke 36878,15:s=36876
  18. 180 gosub20
  19. 190 sc=0:for t=1 to 10
  20. 200 print"[147][144]":for i=1to5:printl$:next
  21. 210 n1=int(9*rnd(0)):p1=7796+n1*22
  22. 220 poke p1,81:poke p1+30720,2
  23. 230 n2=int(9*rnd(0)):p2=7802+n2*22
  24. 240 poke p2,81:poke p2+30720,2
  25. 250 a=sgn(n1-n2)+2:fl=0
  26. 260 poke s,237:gosub 30
  27. 270 print"f1  up":print"f3  same":print"f5  down"
  28. 280 get a$:if a$=""then 280
  29. 290 if asc(a$)<133 or asc(a$)>135 then 280
  30. 300 if asc(a$)=b(a) then 350
  31. 310 fl=1:poke s,159:gosub 30
  32. 320 poke s,135:gosub 30:goto 280
  33. 350 poke s,f(n1):gosub 40
  34. 360 poke s,f(n2):gosub 40
  35. 370 if fl=0 then sc=sc+1
  36. 380 next t
  37. 390 print "score = ";sc;"out of 10"
  38. 400 print "try again? (y/n)"
  39. 410 get a$:if a$="y" then 190
  40. 420 if a$<>"n" then 410
  41. 430 print"[147]":end
  42.